Login | Register   
LinkedIn
Google+
Twitter
RSS Feed
Download our iPhone app
TODAY'S HEADLINES  |   ARTICLE ARCHIVE  |   FORUMS  |   TIP BANK
Browse DevX
Sign up for e-mail newsletters from DevX


Tip of the Day
Language: Visual Basic
Expertise: Intermediate
Feb 3, 1999

Slam Selected Items Into an Array

Use this code to retrieve all selected list items in a multiselect-style listbox in one API call. It's a lot easier than iterating through a large list using For...Next. This code works against both normal and checkbox-style lists:
 
Private Declare Function SendMessage Lib "user32" Alias _
	"SendMessageA" (ByVal hWnd As Long, ByVal wMsg _
	As Long, ByVal wParam As Long, lParam As Any) As Long

Private Const LB_GETSELCOUNT = &H190
Private Const LB_GETSELITEMS = &H191

Private Sub Command1_Click()
	Dim numSelected As Long
	Const LB_ERR = -1
	Dim r As Long
	Dim i As Integer

	'get the number of items selected.

	'If the listbox is single-select style,
	'numSelected will return -1 (LB_ERR).
	'If the listbox is multiselect style,
	'and nothing is selected, numSelected
	'returns 0. Otherwise, numSelected returns
	'the number selected (ala List1.SelCount)
	numSelected = SendMessage(List1.hWnd, LB_GETSELCOUNT, _
		0&, ByVal 0&)

	'debug ...
	Debug.Print numSelected; " items selected:"
	Debug.Print "index", "item"

	If numSelected <> LB_ERR Then
		'dim an array large enough to hold
		'the indexes of the selected items
		ReDim sSelected(1 To numSelected) As Long

		'pass the array so SendMessage can fill
		'it with the selected item indexes
		Call SendMessage(List1.hWnd, LB_GETSELITEMS, _
			numSelected, sSelected(1))

		'debug ...
		'print out the items selected
		'note that their index is 0-based
		For i = 1 To numSelected
			Debug.Print List1.List(sSelected(i))
		Next
	End If
End Sub
Randy Birch
 
Comment and Contribute

 

 

 

 

 


(Maximum characters: 1200). You have 1200 characters left.

 

 

Sitemap
Thanks for your registration, follow us on our social networks to keep up-to-date