Get the Command$ value from inside an ActiveX DLL

Private Declare Function GetCommandLine Lib "kernel32" Alias "GetCommandLineA" _
    () As Long
Private Declare Function lstrcpy Lib "kernel32" Alias "lstrcpyA" (ByVal _
    lpString1 As String, ByVal lpString2 As Long) As Long

' inside the ActiveX DLL
    
Dim lpStr As Long, i As Long
Dim buffer As String
Dim exePath As String, cmdLine As String
    
' get a pointer to the command line
lpStr = GetCommandLine()
' copy into a local buffer
buffer = Space$(512)
lstrcpy buffer, lpStr
' extract the null-terminated string
buffer = Left$(buffer, InStr(buffer & vbNullChar, vbNullChar) - 1)
    
If Left$(buffer, 1) = """" Then
    ' if the string begins with double quotes,
    ' find the closing quotes
    i = InStr(2, buffer, """")
    exePath = Mid$(buffer, 2, i - 2)
    ' the rest of the line is the command line
    cmdLine = LTrim$(Mid$(buffer, i + 1))
Else
    ' otherwise just find the space that separates
    ' the EXE name/path and the command line
    i = InStr(buffer, " ")
    exePath = Left$(buffer, i - 1)
    cmdLine = LTrim$(Mid$(buffer, i))
End If