Login | Register   
LinkedIn
Google+
Twitter
RSS Feed
Download our iPhone app
TODAY'S HEADLINES  |   ARTICLE ARCHIVE  |   FORUMS  |   TIP BANK
Browse DevX
Sign up for e-mail newsletters from DevX


Tip of the Day
Language: VB5,VB6
Expertise: Advanced
Dec 16, 2000

Determine when a ComboBox's area is being closed

The ComboBox control exposes the DropDown event, that lets you determine when its list area is being opened. However, VB doesn't offer any simple way to understand when the list area is being closed. You can achieve this by intercepting the WM_COMMAND message that the ComboBox control sends to its container (can be the parent form, or a container control such as a PictureBox control). The following code shows how you can trap this message using the MsgHook component (that you can download from the File Bank section of this site):

' REQUIRES THE MSGHOOK.DLL COMPONENT

Const WM_COMMAND = &H111
Const CBN_DROPDOWN = 7
Const CBN_CLOSEUP = 8

Dim WithEvents FormHook As MsgHook

Private Sub Form_Load()
    ' subclass the form with events
    Set FormHook = New MsgHook
    ' you should pass the hWnd of the combobox container
    FormHook.StartSubclass Me.hWnd
End Sub

Private Sub FormHook_AfterMessage(ByVal uMsg As Long, ByVal wParam As Long, _
    ByVal lParam As Long, retValue As Long)
    Dim Ctrl As Control
    Dim ctrlIndex As Long
    Dim cmdCode As Long
    
    If uMsg = WM_COMMAND Then
        ' on entry, lParam holds the hWnd of the control
        ' the high word of wParam contains the actual command code
        ' the low word of wParam contains the control ID
        ' ( this is the index of the control in the Controls collection + 1)
        ctrlIndex = (wParam And &HFFFF&) - 1
        Set Ctrl = Me.Controls(ctrlIndex)
        cmdCode = (wParam And &HFFFF0000) \ &H10000

        If Not TypeOf Ctrl Is ComboBox Then
            ' this should never happen
        ElseIf cmdCode = CBN_DROPDOWN Then
            ' the list area is being opened
            Debug.Print Ctrl.Name & " is being opened"
        ElseIf cmdCode = CBN_CLOSEUP Then
            ' the list area is being closed
            Debug.Print Ctrl.Name & " is being closed"
        End If
    End If
End Sub


Francesco Balena
 
Comment and Contribute

 

 

 

 

 


(Maximum characters: 1200). You have 1200 characters left.

 

 

Sitemap