Retrieve information on all available drives

' NOTE: this code requires that you add a reference to the
'       Microsoft Scripting Runtime type library

Dim fso As New Scripting.FileSystemObject
Dim drv As Scripting.Drive
Dim info As String

For Each drv In fso.Drives
    ' display drive name and type
    info = "Drive " & drv.DriveLetter & vbCrLf
    info = info & "  Type: "
    ' we must decode this value
    Select Case drv.DriveType
        Case Removable: info = info & "Removable" & vbCrLf
        Case Fixed: info = info & "Fixed" & vbCrLf
        Case CDRom: info = info & "CDRom" & vbCrLf
        Case Remote: info = info & "Remote" & vbCrLf
        Case RamDisk: info = info & "RamDisk" & vbCrLf
        Case Else: info = info & "Unknown" & vbCrLf
    End Select

    If Not drv.IsReady Then
        ' if the drive isn't ready we can't do much more
        info = info & "  Not Ready" & vbCrLf
    Else
        ' retreive all additional info
        info = info & "   File System: " & drv.FileSystem & vbCrLf
        info = info & "   Label: " & drv.VolumeName & vbCrLf
        info = info & "   Serial number: " & drv.SerialNumber & vbCrLf
        info = info & "   Total space: " & drv.TotalSize & vbCrLf
        info = info & "   Free space: " & drv.FreeSpace & vbCrLf
    End If
    
    ' do something with the gathered info
    ' (display in a textbox in this case)
    Text1.Text = Text1.Text & info
Next