Login | Register   
LinkedIn
Google+
Twitter
RSS Feed
Download our iPhone app
TODAY'S HEADLINES  |   ARTICLE ARCHIVE  |   FORUMS  |   TIP BANK
Browse DevX
Sign up for e-mail newsletters from DevX


Tip of the Day
Language: VB5,VB6
Expertise: Intermediate
Sep 12, 2002

GetRoshHashanah - Get the date of Rosh Hashanah (Jewish calendar)


' Returns the date that Rosh Hashanah begins
' for the requested year.  It is important to note that
' Rosh Hashanah is based on the Lunar cycle so the Holiday
' actually begins at sunset of the day before the date
' returned by this function.

' Note: Many dates in the Jewish calendar are dependent on the date
 'of Rosh Hashanah just as Good Friday, Lent, and other dates 
' are dependent on Easter.  

Public Function GetRoshHashanah(iYear As Integer) As Date
    
    Dim dDate As Single, iDate As Integer, iDayOfWeek As Integer
    Dim JY As Integer, JtoG As Integer, iMonth As Integer
    
    ' Conversion factors
    Const F1 As Single = 765433 / 492480
    Const F2 As Single = 23269 / 25920
    Const F3 As Single = 765433 / 492480
    
    JY = (12 * ((iYear Mod 19) + 1)) Mod 19
    
    ' Correct from Julian date to Gregorian date
    JtoG = iYear \ 100 - iYear \ 400 - 2
    
    dDate = JtoG + F1 * JY + (iYear Mod 4) / 4 - (313 * CLng(iYear) + 89081) / _
        98496
    
    ' Get the integer portion of the date
    iDate = Int(dDate)
    ' Get the fractional portion of the date
    dDate = dDate - iDate
    
    If iDate > 30 Then
        iDate = iDate - 30
        iMonth = 10
    ElseIf iDate < 1 Then
        iDate = iDate + 31
        iMonth = 8
    Else
        iMonth = 9
    End If
    
    iDayOfWeek = Weekday(DateSerial(iYear, iMonth, iDate))
    
    ' Postponement Rules
    ' If day of week is Sunday, Wednesday, or Friday
    If iDayOfWeek = 1 Or iDayOfWeek = 4 Or iDayOfWeek = 6 Then
        iDate = iDate + 1
    ' If day is Monday
    ElseIf iDayOfWeek = 2 And dDate > F1 And JY > 11 Then
        iDate = iDate + 1
    ' If day is Tuesday we may need to add two days
    ElseIf iDayOfWeek = 3 And dDate >= F2 And JY > 6 Then
        iDate = iDate + 2
    End If
    
    If iDate > 30 Then
        iDate = iDate - 30
        iMonth = 10
    ElseIf iDate < 1 Then
        iDate = iDate + 31
        iMonth = 8
    Else
        iMonth = 9
    End If
    
    GetRoshHashanah = DateSerial(iYear, iMonth, iDate)
    
End Function

Jim Edgar
 
Comment and Contribute

 

 

 

 

 


(Maximum characters: 1200). You have 1200 characters left.

 

 

Sitemap
Thanks for your registration, follow us on our social networks to keep up-to-date