Login | Register   
LinkedIn
Google+
Twitter
RSS Feed
Download our iPhone app
TODAY'S HEADLINES  |   ARTICLE ARCHIVE  |   FORUMS  |   TIP BANK
Browse DevX
Sign up for e-mail newsletters from DevX


Tip of the Day
Language: VB5,VB6
Expertise: Intermediate
Aug 11, 2001

URLEncodeEx - Apply URL encoding rules

' Applies URL encoding rules to the specified Text and returns the result
' (similar to Server.URLEncode)

Public Function URLEncodeEx(ByVal Text As String) As String
    
    Dim abytTokens() As Byte
    Dim lngTotal As Long
    Dim lngCount As Long
    Dim astrReturn() As String
    Dim strReturn As String
    
    strReturn = Text
    
    If Trim$(strReturn) <> "" Then
        ' convert to an array
        abytTokens = StrConv(Text, vbFromUnicode)
        
        lngTotal = UBound(abytTokens)
        
        ' dimension enough space for the return
        ReDim astrReturn(lngTotal)
        
        For lngCount = 0 To lngTotal
            Select Case abytTokens(lngCount)
                Case 48 To 57, 65 To 90, 97 To 122
                    ' don't touch alphanumeric chars
                    astrReturn(lngCount) = Chr$(abytTokens(lngCount))
                Case 32
                    astrReturn(lngCount) = "+"
                Case Else
                    If abytTokens(lngCount) < 16 Then
                        astrReturn(lngCount) = "%0" & Hex$(abytTokens(lngCount))
                    Else
                        astrReturn(lngCount) = "%" & Hex$(abytTokens(lngCount))
                    End If
            End Select
        Next ' lngCount
        strReturn = Join(astrReturn, "")
    
        Erase astrReturn
        Erase abytTokens
    End If
    
    ' join the return tokens together
    URLEncodeEx = strReturn
    
End Function


'###################################
'#
'# This tip has been brought to you by www.omnisolvonline.com,
'# makers of a host of software development, energy and information 
'# management tools.
'#
'###################################

Paul McEwan
 
Comment and Contribute

 

 

 

 

 


(Maximum characters: 1200). You have 1200 characters left.

 

 

Sitemap
Thanks for your registration, follow us on our social networks to keep up-to-date