PlayAVIAudioOFF - Playing an AVI file synchronously without the audio track

<System.Runtime.InteropServices.DllImport("kernel32.dll")> Shared Function _
    GetShortPathName(ByVal lpszLongPath As String, _
    ByVal lpszShortPath As System.Text.StringBuilder, _
    ByVal cchBuffer As Integer) As Integer
End Function

' Play an AVI file synchronously without the audio track.
'
' fileName is a string containing the full path of the file.
'
' Notes: requires the ExecuteMCICommand routine

Sub PlayAVIAudioOFF(ByVal fileName As String)
    Dim commandString As String
    Dim shortFileName As New System.Text.StringBuilder(260)

    ' retrieve the file name in the short format (8+3 chars)
    GetShortPathName(fileName, shortFileName, shortFileName.Capacity)
    fileName = shortFileName.ToString()

    ' open the device
    commandString = "open " & fileName & " type avivideo alias AVIFile"
    ExecuteMCICommand(commandString, False)

    ' set audio OFF
    commandString = "set AVIFile audio all off"
    ExecuteMCICommand(commandString, True)

    ' play the file
    commandString = "play AVIFile wait"
    ExecuteMCICommand(commandString, True)

    ' close the device
    commandString = "close AVIFile"
    ExecuteMCICommand(commandString, True)
End Sub