To retrieve the required field from the table based on the supplied condition, use the following code:
Function GetQueryResults(strSql As String, Optional ReadOnly As Boolean = True) _
As Recordset
Dim rstQueryResult As Recordset
Set rstQueryResult = New Recordset
strSql = GetQueryString(strSql)
rstQueryResult.CursorLocation = adUseClient
' gCnn is the Connection Object
rstQueryResult.Open strSql, gCnn, IIf(ReadOnly, adOpenStatic, adOpenKeyset), _
IIf(ReadOnly, adLockReadOnly, adLockOptimistic)
Set GetQueryResults = rstQueryResult
Set rstQueryResult = Nothing
End Function
Function GetFieldfromTable(TblName As String, FldName As String, Optional Cond As String = "") _
As String
' Input : TblName - Name of the table from which Field has to be retrieved
' FldName - Name of the Field to be retrieved
' Cond - Condition basis to retrieve field
Dim rst As Recordset
Dim strSql As String
GetFieldfromTable = ""
strSql = "Select " & FldName & " FROM " & TblName & IIf(Cond <> "", " WHERE " & Cond, "")
Set rst = GetQueryResults(strSql)
With rst
If Not (.EOF Or .BOF) Then
If Not IsNull(.Fields(0)) Then GetFieldfromTable = .Fields(0)
End If
End With
Set rst = Nothing
End Function
